With[{style = 9}, GraphicsGrid[Partition[{
    PolarPlot[1 - Sin[t], {t, 0, 2 \[Pi]}, Ticks -> None, 
     PlotStyle -> Red,
     PlotLabel -> r == 1 - Sin[\[Theta]], 
     BaseStyle -> {style, FontSize -> 18}],
    ContourPlot[-x^2 z^3 + (-1 + x^2 + z^2)^3, {x, -1.2, 1.2}, {z, -1,
       1.3}, Contours -> {0}, ContourShading -> False, Frame -> False,
      PlotLabel -> -x^2 y^3 + (-1 + x^2 + y^2)^3 == 0, 
     ContourStyle -> Red, Axes -> True, Ticks -> None, 
     BaseStyle -> {style, FontSize -> 18}],
    ParametricPlot[{Log[Abs[t]] Sin[t] Cos[t], 
      Abs[t]^.3 Sqrt[Cos[t]]}, {t, -1, 1},
     AspectRatio -> Automatic, BaseStyle -> {style, FontSize -> 18},
     PlotPoints -> 100, PlotStyle -> Red, PlotRange -> All, 
     Ticks -> False, 
     PlotLabel -> 
      Column@Thread[{x, y} == {Log[Abs[t]] Sin[t] Cos[t], 
          Abs[t]^.3 Sqrt[Cos[t]]}]],
    Plot[2/
          3 ((x^2 + Abs[x] - 6)/(x^2 + Abs[x] + 2)) + # (36 - x^2)^(1/
            2) & /@ {-1, 1}, {x, -6, 6}, PlotStyle -> Red, 
     BaseStyle -> {style, FontSize -> 18}, AspectRatio -> Automatic, 
     Ticks -> False, 
     PlotLabel -> (y - (2/
              3 ((x^2 + Abs[x] - 6)/(x^2 + Abs[x] + 2))))^2 + x^2 == 
       36],
    PolarPlot[
     2 - 2 Sin[t] + Sin[t] Sqrt[Abs[Cos[t]]]/(Sin[t] + 7/5), {t, 0, 
      2 \[Pi]}, PlotStyle -> Red, Ticks -> False, 
     PlotLabel -> 
      r == 2 - 2 Sin[t] + Sin[t] Sqrt[Abs[Cos[t]]]/(Sin[t] + 7/5), 
     BaseStyle -> {style, FontSize -> 18}],
    ParametricPlot[
     par = {16 Sin[t]^3, 
       13 Cos[t] - 5 Cos[2 t] - 2 Cos[3 t] - 
        Cos[4 t]}, {t, -\[Pi], \[Pi]},
     AspectRatio -> Automatic, BaseStyle -> {style, FontSize -> 18},
     PlotPoints -> 100, PlotStyle -> Red, PlotRange -> All, 
     Ticks -> False, 
     PlotLabel -> 
      TextCell[
       Column[Thread[{x, y} == {16 Sin[t]^3, 
           13 Cos[t] - 5 Cos[2 t] - 2 Cos[3 t] - Cos[4 t]}], 
        Alignment -> Left], PageWidth -> 500/3]]
    }, 3, 3, {1, 1}, {}], ImageSize -> 1920]
 ]

http://mathworld.wolfram.com/HeartCurve.html

This will create a graphic that has six versions of the curve in one

The Heart Curve

Other