Mother 3 Translation Blog RSS Tidy Up

#!/usr/bin/perl -w
 
use strict;
use LWP::Simple;
use HTML::TreeBuilder;
use LWP::Parallel::UserAgent;
use XML::TreeBuilder;
use Encode;
 
my $ua = LWP::Parallel::UserAgent->new();
print STDERR "Grabbing feed XML...\n";
my $xml = get("http://feeds.feedburner.com/Mother3FanTranslation?format=xml");
my $atomfeed = XML::TreeBuilder->new();
$atomfeed->parse($xml);
my %entries;
 
print STDERR "Scraping links from XML...\n";
foreach my $item ($atomfeed->look_down("_tag", "item")) {
	my $link = $item->look_down("_tag", "link")->as_text();
	$entries{$link} = $item;
}
 
foreach my $item ($atomfeed->look_down("_tag", "item")) {
	my $url = $item->look_down("_tag", "link")->as_text();
	my $request = HTTP::Request->new();
 
	$request->uri($url);
	$request->method("GET");
 
	print STDERR "Registering $url...\n";
	$ua->register($request);	
}
 
print STDERR "Downloading HTML...";
my $html = $ua->wait();
print STDERR "done!\n";
 
foreach my $entry (values(%$html)) {
	my $response = $entry->response();
	my $url = $response->base()->as_string();
 
	print STDERR "Processing $url...\n";
	my $item = $entries{$url};
 
	print STDERR "\tDeleting description content...\n";
	my $description = $item->look_down("_tag", "content:encoded");
	$description->delete_content();
 
	print STDERR "\tGrabbing relavent HTML via regular expression...\n";
	my $blogentry = $response->content();
	(undef, my $blogtree) = ($blogentry =~ m/<p class="meta">(.*?)<\/p>(.*?)<p class="meta">Posted/s);
 
	my $html = HTML::TreeBuilder->new_from_content(
		decode_utf8($response->content())
	);
 
	my $comments = "<br /><br />Mato Comments:<br />";
 
	print STDERR "\tFinding Mato comments...\n";
	foreach ($html->look_down("_tag", "div", "style", qr/DCB6B6/)) {
			print STDERR "\t\tFound a comment!\n";
			foreach ($_->look_down("_tag", "p")) {
				$comments .= "<blockquote>".$_->as_HTML()."</blockquote>";
			}
	}
 
	$blogtree = HTML::TreeBuilder->new_from_content(
		decode_utf8($blogtree.$comments)
	);
 
	print STDERR "\tCleaning up HTML for Liferea...\n";
	foreach my $hrdiv ($blogtree->look_down("_tag", "div", "class", "hr")) {
		$hrdiv->delete();
	}
 
 
 
	print STDERR "\tPushing content to $url entry...\n";
	$description->push_content($blogtree->as_HTML());
}
 
print $atomfeed->as_XML();