compile java into output dir >> DOS batch

@echo off
SET output_new="output" dir created
SET output_err="output" dir cant be created, because there is a file in current dir having the same name
SET output_wut=an exception occured while creating "output" dir
SET _output=
SET _found=
rem echo processing s1w's compile output..
rem if "%~1" NEQ "" echo parametry: %*
SET _params=%*
 
FOR %%G IN (%*) DO (
 IF DEFINED _found (
  call :pTrim %%G _output
  call :clearParams %%G
  goto :check dir
 )
 IF /I [%%G]==[-d] (
  SET _found=true
 )
)
call :makedir "%CD%\output" _output
goto :eof
 
 
:check dir
SET _lastdir=
SET _path=
call :lastdir %_output% _lastdir
call :path %_output% _path
IF NOT EXIST %_path% goto :not_dir
IF NOT EXIST %_output% (
 if "%_lastdir%"=="output" (
  call :makedir %_output% _output
  goto :eof
 )
:not_dir
 echo bledny folder docelowy! %_output%
 goto :err
) ELSE (
 if "%_lastdir%"=="output" (
  cmd /c cd %_output% 2>nul && (goto :compile) || (echo %output_err%&&goto :err)
 )
 cmd /c cd %_output% 2>nul || (goto :not_dir)
 call :makedir %_output%\output _output
 goto :eof
)
::below command is simpler, but \nul is not working with long pathes or within quotes
rem IF NOT EXIST %_output%\output\nul MD %_output%\output
 
 
:makedir
 IF "%~2" NEQ "" SET %~2=%1
 md %1 2>nul && (echo %output_new%&&goto :compile)
 IF EXIST %1 (
   cmd /c cd %1 2>nul && (goto :compile) || (echo %output_err%)
 ) ELSE (
   echo %output_wut%
 )
GOTO :err
 
 
:compile
rem set _
 IF EXIST "%~dp0javac.exe" (
   "%~dp0javac" -d %_output% %_params%
  echo.
  echo processed by s1w's batch
 ) ELSE (
  echo.
  echo cannot find javac.exe, you must either update path entry for jdk\bin or reinstall JDK environment
 )
GOTO :success
 
 
:lastdir
 IF "%~2" NEQ "" SET %~2=%~n1
 exit /b
 
:path
 IF "%~2" NEQ "" SET %~2="%~dp1"
 exit /b
 
 
:clearParams path
SETLOCAL EnableDelayedExpansion
 set _tmp=!_params:*-d=-d!
 set _l=%1
 for /f "tokens=1* delims=%_l:~0,1%" %%a in ("!_tmp!") do call set _d=%%a
rem echo do usuniecia [!_d!%1]
 call set _params=%%_params:!_d!%1=%%
 call :sTrim _params
ENDLOCAL & SET _params=%_params%
EXIT /b
 
 
:pTrim string out -- strips white spaces (or other characters) from the path
:$source http://www.dostips.com - s1w mod
call set string=%%~1%
SETLOCAL EnableDelayedExpansion
set max=32
for /f "tokens=*" %%a in ("!string!") do set "string=%%a"
for /l %%a in (1,1,%max%) do (
 set _finish=true
 if "!string:~-1!"==" " set string=!string:~0,-1!
 if "!string:~-1!"=="\" set string=!string:~0,-1!
 if "!string:~-1!"=="/" set string=!string:~0,-1!
 if "!string:~-1!"==" " set _finish=false
 if "!string:~-1!"=="\" set _finish=false
 if "!string:~-1!"=="/" set _finish=false
 if !_finish!==true goto :loopend
)
:loopend
( ENDLOCAL & REM RETURN VALUES
    IF "%~2" NEQ "" (
      SET %~2="%string%"
    ) ELSE (
      IF "%~1" NEQ "" SET %~1="%string%"
    )
)
EXIT /b
 
 
:sTrim string -- strips white spaces from the string - s1w
SETLOCAL EnableDelayedExpansion
call set string=%%%1%%
set max=32
for /f "tokens=*" %%a in ("!string!") do set "string=%%a"
for /l %%a in (1,1,%max%) do (
 if "!string:~-1!"==" " set string=!string:~0,-1!
 if NOT "!string:~-1!"==" " goto :loopend
)
:loopend
( ENDLOCAL & REM RETURN VALUES
    IF "%~1" NEQ "" SET %~1=%string%
)
EXIT /b
 
 
:err
 echo.
 echo compilation suppressed
:success
 EXIT /b