Access Plain Text Export

Option Compare Database
Option Explicit
 
Public Function PlainTextExport()
On Error GoTo Err_ExportDatabaseObjects
 
    Dim db As Database
    'Dim db As DAO.Database
    Dim td As TableDef
    Dim D As Document
    Dim c As Container
    Dim i As Integer
    Dim sExportLocation As String
 
    Set db = CurrentDb()
 
    sExportLocation = GetDBPath & "\exports\"
 
   ' For Each td In db.TableDefs 'Tables
     '   If left(td.Name, 4) <> "MSys" Then
      '      DoCmd.TransferText acExportDelim, , td.Name, sExportLocation & "Table_" & td.Name & ".txt", True
      '  End If
   ' Next td
 
    Set c = db.Containers("Forms")
    For Each D In c.Documents
        Application.SaveAsText acForm, D.Name, sExportLocation & "Form_" & D.Name & ".txt"
    Next D
 
    Set c = db.Containers("Reports")
    For Each D In c.Documents
        Application.SaveAsText acReport, D.Name, sExportLocation & "Report_" & D.Name & ".txt"
    Next D
 
    Set c = db.Containers("Scripts")
    For Each D In c.Documents
        Application.SaveAsText acMacro, D.Name, sExportLocation & "Macro_" & D.Name & ".txt"
    Next D
 
    Set c = db.Containers("Modules")
    For Each D In c.Documents
        Application.SaveAsText acModule, D.Name, sExportLocation & "Module_" & D.Name & ".txt"
    Next D
 
    For i = 0 To db.QueryDefs.Count - 1
        Application.SaveAsText acQuery, db.QueryDefs(i).Name, sExportLocation & "Query_" & db.QueryDefs(i).Name & ".txt"
    Next i
 
    Set db = Nothing
    Set c = Nothing
 
    MsgBox "All database objects have been exported as a text file to " & sExportLocation, vbInformation
 
Exit_ExportDatabaseObjects:
    Exit Function
 
Err_ExportDatabaseObjects:
    MsgBox Err.Number & " - " & Err.Description
    Resume Exit_ExportDatabaseObjects
 
End Function
 
 
 
'gibt den Pfad der Datenbank zurück
Public Function GetDBPath() As String
    Dim strFullPath As String
    Dim i As Integer
 
    strFullPath = CurrentDb().Name
 
    For i = Len(strFullPath) To 1 Step -1
        If Mid(strFullPath, i, 1) = "\" Then
            GetDBPath = Left(strFullPath, i)
            Exit For
        End If
    Next
End Function