AS2 CASA ロードした画像をタイル上に並べる

import org.casaframework.load.data.xml.XmlLoad;
import org.casaframework.util.XmlUtil;
import org.casaframework.load.LoadGroup;
import org.casaframework.load.media.MediaLoad;
import org.casaframework.math.geom.Rectangle;
import org.casaframework.layout.DistributionCollection;
 
var xmlObject:Object;
var myLoadGroup:LoadGroup;
var myXmlLoad:XmlLoad;
 
loadXmlData();
 
// XML 読み込み
function loadXmlData(){
	trace("xml start");
	this.myXmlLoad = new XmlLoad('data/sample.xml'); // xmlのパスを記入
	this.myXmlLoad.addEventObserver(this, XmlLoad.EVENT_LOAD_COMPLETE, 'onXmlLoad');
	this.myXmlLoad.start();
}
 
// XML読み込み完了
function onXmlLoad(){
	trace("xml load complete");
	this.xmlObject = XmlUtil.xmlToObject(this.myXmlLoad.getXml())['data'][0]['block']; // + 〜getXml())['data'][0]['keyword']でxmlのルート-0番目->一番目の要素...と取り出す
	init();
}
 
function init():Void {
	myLoadGroup = new LoadGroup();
	trace(xmlObject.length);
    for (var i:Number = 0; i<xmlObject.length; i++) {
        var rect:MovieClip = this.createEmptyMovieClip("rect"+i,getNextHighestDepth());
		var holder:MovieClip =rect.createEmptyMovieClip("holder",getNextHighestDepth());
		myLoadGroup.addLoad(new MediaLoad(holder,xmlObject[i].img[0].nodeValue)); // ロードする画像のパスの位置
    }
	myLoadGroup.addEventObserver(this, LoadGroup.EVENT_LOAD_COMPLETE, "onGroupLoadComplete");
	myLoadGroup.start();
}
 
 
function onGroupLoadComplete(){
	trace("全画像ロード完了");
	//loading._visible = false;
	var _dist:DistributionCollection;
	_dist = new DistributionCollection( true );
	_dist.setRectangle(new Rectangle(0, 0, 350, Number.POSITIVE_INFINITY));
	_dist.setMargin(10, 10, 10, 10);
	var thumbs:Array = myLoadGroup.getLoads();
	trace(thumbs.length);
	for(var i:Number=0;i<thumbs.length;i++){
		var mc:MovieClip = thumbs[i].getMovieClip();
		//配列に格納される順番が逆転してるのに注意！
		trace(thumbs[i].getMovieClip());
		//CASA のドキュメントのサンプルはライブラリの中からシンボルを attachMovie してるサンプルなので、
		//今回は mc を追加していくだけでOKです。
		_dist.addItem(mc);
	}
	_dist.positionItems();
	trace(_dist);
}