AS2 MdN ランダムにトランジション 画面遷移ライブラリ

/* ここから */
/*
ランダムなトランジション
ランダムに画面を切り替える実行部分とライブラリ
まず1〜5の画像をロード
*/
 
/* ここから 実行部分 */
import mx.transitions.*;
import mx.transitions.easing.*;
 
var cnt:Number = 0;
var index:Number = 0;
var imageArray:Array = new Array();
var base_mc:MovieClip = this.createEmptyMovieClip("base_mc", 1);
var mclListener:Object = new Object();
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
 
for (var i=0; i<5; i++) {
var mc1:MovieClip = this.createEmptyMovieClip("image_mc1"+i,10+i);
var mc2:MovieClip = mc1.createEmptyMovieClip("image_mc2"+i, 100+i);
 
image_mcl.loadClip(1+i+".jpg", mc2);
}
 
mclListener.onLoadInit = function(mc:MovieClip) {
base_mc._x=5;
base_mc._y=5;
mc._x=-mc._width/2;
mc._y=-mc._height/2;
mc._parent._x=mc._width/2;
mc._parent._y=mc._height/2;
mc._visible=false;
imageArray.push (mc)
imageArray.sort (16)
 
	if(cnt==4){
		set_c(base_mc,[1,0x000000,100],[0xffffff,100],mc._height,mc._width)
		setImage(mc);
		}
  cnt++;
	};
 
	function upData():Void {
 
	index++;
	index %= imageArray.length;
	firstImage(imageArray[index])
 
	  }
 
	function firstImage(mc:MovieClip):Void {
 
	mc._visible=true;
	mc._parent.swapDepths( this.getNextHighestDepth())
    img_go(mc) 
 
	}
 
function setImage(mc:MovieClip):Void {
	   var startTime:Number;
	   var timeOut:Number = 1000;
	   startTime= getTimer();
	   base_mc.onEnterFrame = function(){
	   if(getTimer() > startTime+timeOut){
	   var tt=(0-this._x)/3;
	   var hh=(0-this._y)/3
		if(Math.abs(tt)<0.1 && Math.abs(hh)<0.1 ){
				this._x =0;
				this._y =0;
				delete this.onEnterFrame;
				drop(this);
				firstImage(mc);
                SlideImageID=setInterval(upData,5000);
				}else{
				this._x += tt;
				this._y += hh;
 
				}
	   }
 
	   }
}
 
function goOut(mc:MovieClip):Void{
 
	var myTween4:Tween= new Tween(mc._parent, "_alpha", Strong.easeIn, 100, 0, 8, true);
 
}
 
function set_c(_mc,line_style, fill_style,he,wi):Void {
 
	if (line_style)_mc.lineStyle.apply(_mc, line_style);
	if (fill_style) _mc.beginFill.apply(_mc, fill_style);
 
	_mc.moveTo(0,0);
	_mc.lineTo(0, he-1);
    _mc.lineTo(wi-1, he-1);
	_mc.lineTo(wi-1,0);
	_mc.lineTo(0, 0);
	if (fill_style) _mc.endFill();
 
	}
 
function drop(target_mc:MovieClip):Void{
 
var distance:Number = 5;
var angleInDegrees:Number = 45;
var color:Number = 0x000000;
var alpha:Number = .8;
var blurX:Number = 7;
var blurY:Number = 7;
var strength:Number = 1;
var quality:Number = 3;
var inner:Boolean = false;
var knockout:Boolean = false;
var hideObject:Boolean = false;
 
var filter =  new flash.filters.DropShadowFilter(distance, 
                                                    angleInDegrees, 
                                                    color, 
                                                    alpha, 
                                                    blurX, 
                                                    blurY, 
                                                    strength, 
                                                    quality, 
                                                    inner, 
                                                    knockout, 
                                                    hideObject);
var filterArray:Array = target_mc.filters;
filterArray.push(filter);
target_mc.filters = filterArray;
 
	}
 
function img_go(mc:MovieClip):Void {
	var imgArray = ["roTra", "phTra", "sqTra", "flyTra", "pdTra","blTra","faTra","irTra","wiTra","zoTra"];
	this[imgArray[Math.floor(Math.random()*imgArray.length)]](mc);
 
	goOut(mc)
		}
 
 
/* ここまで 実行部分 */
 
/* ここから ライブラリ */
import mx.transitions.*;
import mx.transitions.easing.*;
 
function roTra(mc:MovieClip):Void {
	 var myTween:Tween= new Tween(mc, "_alpha", Strong.easeIn, 0, 100, 2, true);
	TransitionManager.start(mc._parent, {type:Rotate, direction:Transition.IN, duration:3, easing:Strong.easeInOut, ccw:false, degrees:720});
}
function phTra(mc:MovieClip):Void {
	var myTween1:Tween= new Tween(mc, "_alpha", Strong.easeIn, 0, 100, 10, false);
	TransitionManager.start (mc._parent, {type:Photo, direction:Transition.IN, duration:2, easing:Elastic.easeOut});
}
function sqTra(mc:MovieClip):Void {
	var myTween2:Tween= new Tween(mc, "_alpha", Strong.easeIn, 0, 100, 10, false);
	TransitionManager.start(mc._parent, {type:Squeeze, direction:Transition.IN, duration:3, easing:Elastic.easeOut, dimension:0});
}
function flyTra(mc:MovieClip):Void {
	var myTween3:Tween= new Tween(mc, "_alpha", Strong.easeIn, 0, 100, 25, false);
	TransitionManager.start(mc._parent, {type:Fly, direction:Transition.IN, duration:3, easing:Elastic.easeOut, startPoint:9});
}
function pdTra(mc:MovieClip):Void {
 
	TransitionManager.start(mc._parent, {type:PixelDissolve, direction:Transition.IN, duration:2, easing:None.easeNone, xSections:20, ySections:20});
 
	}
function blTra(mc:MovieClip):Void {
 
	TransitionManager.start(mc._parent, {type:Blinds, direction:Transition.IN, duration:2, easing:None.easeNone, numStrips:15, dimension:1});
 
	}
	function faTra(mc:MovieClip):Void {
 
	TransitionManager.start(mc, {type:Fade, direction:Transition.IN, duration:3, easing:Strong.easeIn});
 
	}
function wiTra(mc:MovieClip):Void {
 
	TransitionManager.start(mc._parent, {type:Wipe, direction:Transition.IN, duration:2, easing:None.easeNone, startPoint:1}); 
 
	}
	function irTra(mc:MovieClip):Void {
 
	TransitionManager.start(mc._parent, {type:Iris, direction:Transition.IN, duration:2, easing:Strong.easeOut, startPoint:5, shape:Iris.CIRCLE});
 
	}
function zoTra(mc:MovieClip):Void {
 
	TransitionManager.start(mc._parent, {type:Zoom, direction:Transition.IN, duration:2, easing:Elastic.easeOut});
 
	}
/* ここまで ライブラリ */