RandomText AS2

class RandomText extends MovieClip{
 
    //***********************************************************************************
    //  by Albo
    // 
    //  Genera una animazione di caratteri randomizzati fino al completamento del
    //  testo specificato passato come parametro del metodo setRandomText
    //  _________________________________________________________________________________
    //
    //  USO:
    // 
    //  /* non embedded fonts */
    //  import RandomText;
    //  var rt:RandomText = new RandomText();
    //  rt.setTarget(mc);
    //  rt.setFontValues("Arial", 40, "left", 0xCCCCCC, true, null);
    //  rt.setRandomText("This is my text...");
    // 
    //  /* embedded fonts */
    //  var rt:RandomText = new RandomText();
    //  rt.setTarget(mc);
    //  rt.setFontValues("Myriad Web Pro", 20, "left", 0xCC0000, true, "advanced");
    //  rt.setRandomText("This is a random text...");
    //
    //
    //***********************************************************************************
 
    // Inizializzazione oggetto TextFormat
    var myFont:String;   
    var myFontSize:Number;
    var myTextAlign:String;
    var myFontColor:Number;
 
    // Inizializzazione oggetto target MovieClip
    var objTarget:Object;
 
    // Inizializzazione oggetto TextField
    var myBold:Boolean;
    var embFonts:Boolean;
    var antialias:String;
 
    // Inizializzazione parametro
    var stringa:String;
 
 
    //***********************************************************************************
    //
    // Setta i valori per il textformat: tipo di font, dimensione, allineamento,
    //                   colore, grassetto, incorporamento font,
    //                   tipo di antialias
    //
    //***********************************************************************************
 
    function setFontValues(_font, _fontSize, _textAlign, _fontColor, _bold, _embFonts, _antialias) {
        this.myFont = _font;
        this.myFontSize = _fontSize;
        this.myTextAlign = _textAlign;
        this.myFontColor = _fontColor;
        this.myBold = _bold;
        this.embFonts = _embFonts;
        this.antialias = _antialias;
    }
 
 
    //***********************************************************************************
    //
    // Setta il target della mc contenitore della mc che contiene il testo da randomizzare
    //
    //***********************************************************************************
 
    function setTarget(_objTarget) {
        this.objTarget = _objTarget;
    }
 
    //***********************************************************************************
    //
    // Metodo setRandomText: passare come parametro la stringa da randomizzare
    //
    //***********************************************************************************
    function setRandomText(_stringa){
 
        this.stringa = _stringa;
 
        var random_mc:MovieClip = this.objTarget.createEmptyMovieClip("random_mc", objTarget.getNextHighestDepth());
 
        var format_fmt:TextFormat = new TextFormat();
        format_fmt.font = this.myFont;
        format_fmt.size = this.myFontSize;
        format_fmt.align = this.myTextAlign
        format_fmt.color = this.myFontColor;
        format_fmt.bold = this.myBold;
 
        var speed:Number = 10;
        var pausa:Number = 70;
        var len:Number = stringa.length;
        var counter:Number = 0;
        var go:Number = getTimer() + pausa;
        var max:Number = 97;
        var min:Number = 123;
        var intervallo:Number;
        var str:String = undefined;
 
        random_mc.createTextField("random_txt", random_mc.getNextHighestDepth(), null, null, null, null);
 
        function setMatrixText(_stringa){
            str = _stringa.substr(0, counter);
 
            for (var i:Number = 0; i < len; i++){            
                str = str + String.fromCharCode(Math.floor(Math.random()*(max - min)) + min);
            }
 
            if (go < getTimer()){
                go = go + pausa;
                ++counter;
                --len;
            }
 
            random_mc.random_txt.text = str;
            random_mc.random_txt.autoSize = true;
            random_mc.random_txt.embedFonts = this.embFonts;
            random_mc.random_txt.antiAliasType = this.antialias;
            random_mc.random_txt.selectable = false;
 
            random_mc.random_txt.setTextFormat(format_fmt);
 
            random_mc.random_txt._x = 0;
            random_mc.random_txt._y = 0;       
 
            if(len < 0){
                clearInterval(intervallo);
            }
        };
        intervallo = setInterval(setMatrixText, speed, _stringa);   
    }
}