Groovy Series: GroovyBeans & Expando

//GroovyBeans are JavaBeans, just made easier. What exactly is the advantage?
 
//simple groovybean -> note Serializable!
class SimpleBean implements java.io.Serializable
{
	String myProperty
}
def bean1 = new SimpleBean()
bean1.myProperty = "groovy"
assert bean1.myProperty == "groovy"
 
bean1.setMyProperty("grails")
assert bean1.getMyProperty() == "grails"
 
//another bean, just no "javabean"
class AnotherBean
{
	def prop1, prop2, prop3
}
 
new AnotherBean(prop1:"one")
 
def bean2 = new AnotherBean()
assert bean2.prop1 == null
bean2.prop1 = "one"
assert bean2.prop1 == "one"
 
//access to all properties... interestingly "properties" is not a property
bean2.properties.each { name, value -> println "Property: $name -> $value" }
 
//direct field access with .@ operator - dot at
//plus example of using map constructor
class HackedBean
{
	String someValue
 
	def getSomeValue()
	{
		return "always the same"
	}
 
        def internalSomeValue()
        {
                return this.@someValue
        }
}
def bean3 = new HackedBean(someValue:'blubb')
assert bean3.internalSomeValue() == 'blubb'
assert bean3.someValue == 'always the same'
 
// Expando magic.
def dyn = new Expando()
assert dyn.prop1 == null
['one','two','three'].each {
	dyn."$it" = it //dyn[it] = it
}
assert dyn.one == "one"
assert dyn.two == "two"
assert dyn.three == "three"
 
//it even gets better: you can assign "methods" by setting closures
dyn.sayHello = { name -> return "Hello $name" }
assert dyn.sayHello('Martin') == "Hello Martin"