Groovy Series: Closures

3.times { println "Hello" }
 
//Whenever you see the curly braces of a closure think: "new Closure(){}".
def c = { println 'I am a closure' }
c.call()
//.call or just closureName()
c()
 
//as the output of this demo gets messy, we use a closure to print some separators
def sep = { println '-'*45 }
sep()
 
//the nice thing is you can pass closures around, just as parameters
//this will print 'I am a closure' three times, as it is called 
//for each element.
[1,2,3].each(c)
sep()
 
//right, above code does not really make a lot of sense. The nice
//thing is you can pass values to the closure.
//Same example, slightly modified. It will print 1, 4, 9
def square = { value -> println value * value }
[1,2,3].each(square)
sep()
 
//as you can leave out the parenthesis and directly pass a unnamed closure, the following is identical
[1,2,3].each { value -> println value * value }
sep()
 
//Groovy provides a default name for a single parameter passed to a closure: it
//this prints 1,2,3
[1,2,3].each { println it }
sep()
 
//note you can reuse existing methods as closure. Methods are similar to closures, they just got a "name". They can be used as
//closures via the method closure operator .&
class SomeClass {
	void printSomeStuff(userName) {
		println "Stuff for " + userName;
	}
}
def myClass = new SomeClass()
def closureFromClass = myClass.&printSomeStuff
 
//prints Stuff for Dierk
closureFromClass("Dierk")
sep()
 
//prints Stuff for Dierk, Sven, Wilma, Bill
['Dierk','Sven','Wilma','Bill'].each(closureFromClass)
sep()
 
//default values
def greeting = { first, last='Mueller' -> println "$first $last" }
greeting("Hans")
greeting("Michael Schumacher")
sep()
 
//closure.getParameterTypes().size()
def nameMap = ['Udo':'Mueller','Tanja':'Fleisch','Horst':'Hummel']
nameMap.each {first, last='Mueller' -> println "$first $last"}
sep()
nameMap.each { entry -> println "${entry.key} ${entry.value}" }
sep()
 
//Resource handling
def outFile = new File("file.txt")
outFile.withWriter { out -> out << "This is a line" } 
outFile.each { println it }