Groovy Series: Ranges

//Ranges
 
//inclusive range
def inclusiveRange = 1..10
assert inclusiveRange instanceof List
assert inclusiveRange.size() == 10
assert inclusiveRange.contains(10)
 
//exclusive range
def exclusiveRange = 1..<10
assert exclusiveRange.size() == 9
assert !exclusiveRange.contains(10)
 
//sequence from negative to positive values
def negativeToPositive = -5..5
assert negativeToPositive.join(',') == '-5,-4,-3,-2,-1,0,1,2,3,4,5'
 
//negative sequence
def negativeRange = -5..<-10
assert negativeRange.join(',') == '-5,-6,-7,-8,-9'
 
//we need no for loop :-)
//but don't forget the braces around the range... 
def out = new StringBuffer()
(1..10).each { 
	out << it
}
assert out.toString() == '12345678910'
 
//but we can use a for loop if we want
out = new StringBuffer()
def range = 1..10
for (i in range) {
    out << i
}
assert out.toString() == '12345678910'
 
//we can also step through a range
assert (1..10).step(2).join(',') == '1,3,5,7,9'
 
//some more fun with groovy
assert (1..10).reverse().join(',') == '10,9,8,7,6,5,4,3,2,1'
assert (1..10).grep{ it > 5}.size() == 5
 
//using ranges to create a sublist
def largeList = [1,2,3,4,5,6,7,8,9,10]
assert largeList[0..4] == [1,2,3,4,5]
assert largeList[0..<4] == [1,2,3,4]
assert largeList[-1..-3] == [10,9,8]
 
//ranges can be used with grep... here using grep with a list
assert [1,2,3,4,5,6,7,8,9,10,11,12].grep(5..10) == [5,6,7,8,9,10]